Kod źródłowy intra z efektami "plots & dycp". Komentarze dotyczące działania poszczególnych procedur zostaną dodane wkrótce.
 
 

;-------------------------------------
;PLOTS & DYCP INTRO BY SIR ART/CHARGED
;-------------------------------------
*= $4000
TABAND   = $0F00
TABHI    = $0900
TABLO    = $0A00
TABX     = $0E00
TABY     = $0E40
SINTAB   = $0D00
TEXTLO   = $2A
TEXTHI   = $2B
FAZA     = $2C
SEI
LDA #$7F
STA $DC0D
LDA #$00
STA $DC0E
LDA #$01
STA $D01A
LDA #$00
STA $D012
LDA #$0B
STA $D011
LDA #<IRQ0
STA $0314
LDA #>IRQ0
STA $0315
LDX #$00
STX $D020
STX $D021
LDX #$00
L1       LDA #$01
STA $D800,X
STA $D900,X
STA $DA00,X
STA $DB00,X
LDA #$FF
STA $0400,X
STA $0500,X
STA $0600,X
STA $06E8,X
STA $3A00,X
STA $3B00,X
LDA #$00
STA $0800,X
STA $2000,X
STA $2100,X
STA $3000,X
STA $3100,X
STA $3200,X
STA $3300,X
STA $3400,X
STA $3500,X
STA $3600,X
STA $3700,X
INX
BNE L1
LDA #$18
STA $D018
LDA #$C8
STA $D016
JSR WRITE
JSR MAKETAB
JSR PISZ
JSR SCRINI
LDX #$00
KI1      LDA $0C00,X
LDA #$00
STA $04A0,X
LDA $0B00,X
LDA #$00
STA $D8A0,X
INX
CPX #$F0
BNE KI1
JSR SPRINI
LDA #$00
STA $21
STA $23
LDA #$40
STA $22
STA $24
LDA #$00
STA $0D
STA $08
STA $07
STA $06
LDA #$00
TAY
TAX
JSR $1000
CLI
K31      LDA #$00
BEQ K31
JSR LOGO
K2       LDA #$FF
K1       CMP $D012
BNE K1
JSR CZYSC
JSR PLOT
JSR SCROLL
JSR SINSC
JSR BUJANIE
JSR MAKESIN
LDA PLOT+1
CMP #$3F
BEQ K3
INC PLOT+1
K3       LDA $DC01
CMP #$EF
BNE K2
LDA #$A9
STA SCR22
K21      LDA #$FF
K11      CMP $D012
BNE K11
JSR CZYSC
JSR PLOT
JSR SCROLL
JSR SCROLL
JSR SCROLL
JSR SINSC
JSR BUJANIE
JSR MAKESIN
LDA PLOT+1
CMP #$00
BEQ K32
DEC PLOT+1
JMP K21
K32      JSR CZYSC
K33      LDA $08
CMP #$09
BNE K33
LDA #$2000/64
STA $07F8
K34      LDA $08
CMP #$29
BNE K34
LDA #$2000/64
STA $07F9
JSR LOGOUT
LDX #$0F
WAIT144  LDY #$03
LDA #$FF
WAIT13   CMP $D012
BNE WAIT13
WAIT23   CMP $D012
BEQ WAIT23
DEY
BPL WAIT13
DEX
STX $1009
BNE WAIT144
LDA #$00
STA $D418
LDX #$00
W145     LDA #$FF
WAIT14   CMP $D012
BNE WAIT14
WAIT24   CMP $D012
BEQ WAIT24
LDA T1,X
STA IRQ2+1
INX
CPX #$0D
BNE W145
LDA #$0B
STA ABC+1
STA ABD+1
LDX #$00
W1451    LDA #$FF
WAIT141  CMP $D012
BNE WAIT141
WAIT241  CMP $D012
BEQ WAIT241
LDA T2,X
STA IRQ2+1
STA IRQ1+1
STA IRQ3+1
INX
CPX #$0D
BNE W1451
LDX #$00
W1452    LDA #$FF
WAIT142  CMP $D012
BNE WAIT142
WAIT242  CMP $D012
BEQ WAIT242
LDA T1,X
STA IRQ2+1
STA IRQ1+1
STA IRQ3+1
STA IRQ4+1
INX
CPX #$0D
BNE W1452
K35      JMP K35
T1       .BYTE $00,$06,$06,$06
.BYTE $00,$00,$00,$06
.BYTE $06,$00,$00,$06
.BYTE $00
T2       .BYTE $06,$00,$00,$00
.BYTE $06,$06,$06,$00
.BYTE $00,$06,$06,$00
.BYTE $06
IRQ0
LDX #$00
LDY #$06
LDA $06
CMP #$20
BNE Q45
LDA Q3+1
CMP #$B3
BEQ Q451
INC Q3+1
Q451     LDA Q2+1
CMP #$83
BEQ Q45
DEC Q2+1
Q45      LDA Q1+1
CMP #$4F
BEQ G1
INC Q1+1
G1       LDA Q4+1
CMP #$E3
BNE G2
LDA $06
CMP #$20
BEQ G22
INC $06
JMP G22
G2       DEC Q4+1
G22
Q1       LDA #$08
R1       CMP $D012
BNE R1
STX $D020
LDA $06
CMP #$20
BEQ Q2
LDA #$80
DF1      CMP $D012
BNE DF1
JMP Q4
Q2       LDA #$83+$18
R2       CMP $D012
BNE R2
STY $D020
Q3       LDA #$83+$18+1
R3       CMP $D012
BNE R3
STX $D020
Q4       LDA #$27
R4       CMP $D012
BNE R4
STY $D020
LDA Q3+1
CMP #$B2
BNE Q5
LDA #$4E
STA $D012
LDA #<IRQ1
STA $0314
LDA #>IRQ1
STA $0315
Q5       INC $D019
JMP $EA81
IRQ1
LDA #$00
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
STA $D020
STA $D021
ABC      LDA #$3B
STA $D011
LDA #$82
STA $D012
LDA #<IRQ2
STA $0314
LDA #>IRQ2
STA $0315
JSR $1003
LDA #$01
STA K31+1
LDA $D01B
EOR #$03
STA $D01B
INC $08
LDA $08
AND #$3F
STA $08
BNE AS1
LDA $D015
AND #$03
ORA #$01
STA $D015
AS1      LDX $08
LDA $3D40,X
STA $D027
TXA
CLC
ADC #$20
AND #$3F
TAX
BNE AS2
LDA $D015
AND #$03
ORA #$02
STA $D015
TXA
AS2      TAX
LDA $3D40,X
STA $D028
LOP1     INC $D019
JMP $EA81
IRQ2
COL1     LDA #$06
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
STA $D020
STA $D021
ABD      LDA #$1B
STA $D011
LDA #$AA+$08
STA $D012
LDA #<IRQ3
STA $0314
LDA #>IRQ3
STA $0315
LDA #$D8
STA $D016
INC $D019
JMP $EA81
IRQ3
LDA #$00
NOP
NOP
NOP
NOP
NOP
NOP
LDY $0E
LDX #$1C
STA $D020
STX $D018
STA $D021
STY $D016
LDA #$EA-$08
STA $D012
LDA #<IRQ4
STA $0314
LDA #>IRQ4
STA $0315
INC $D019
JMP $EA81
IRQ4
LDA #$06
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
LDX #$18
STA $D020
STX $D018
STA $D021
LDA #$4E
STA $D012
LDA #<IRQ1
STA $0314
LDA #>IRQ1
STA $0315
LDA #$D8
STA $D016
INC $D019
JMP $EA81
SINSC    LDA #$38
STA $31
INC $2F
LDA $2F
AND #$7F
STA $2F
JSR $5000
LDA #$3D
STA $39
LDA FAZA
ASL A
ASL A
ASL A
STA $38
LDY $2F
LDX $3900,Y
LDA $0800
STA $30
LDA #$00
STA $3000,X
STA $3001,X
STA $3002,X
STA $300A,X
STA $300B,X
STA $300C,X
LDY #$00
LDA ($30),Y
AND ($38),Y
STA $3003,X
INY
LDA ($30),Y
AND ($38),Y
STA $3004,X
INY
LDA ($30),Y
AND ($38),Y
STA $3005,X
INY
LDA ($30),Y
AND ($38),Y
STA $3006,X
INY
LDA ($30),Y
AND ($38),Y
STA $3007,X
INY
LDA ($30),Y
AND ($38),Y
STA $3008,X
INY
LDA ($30),Y
AND ($38),Y
STA $3009,X
LDA FAZA
EOR #$07
ASL A
ASL A
ASL A
STA $38
LDY $2F
LDX $3917,Y
LDA $0817
STA $30
LDA #$00
STA $35C0,X
STA $35C1,X
STA $35C2,X
STA $35CA,X
STA $35CB,X
STA $35CC,X
LDY #$00
LDA ($30),Y
AND ($38),Y
STA $35C3,X
INY
LDA ($30),Y
AND ($38),Y
STA $35C4,X
INY
LDA ($30),Y
AND ($38),Y
STA $35C5,X
INY
LDA ($30),Y
AND ($38),Y
STA $35C6,X
INY
LDA ($30),Y
AND ($38),Y
STA $35C7,X
INY
LDA ($30),Y
AND ($38),Y
STA $35C8,X
INY
LDA ($30),Y
AND ($38),Y
STA $35C9,X
RTS
WRITE    LDA #$00
STA $20
LDA #$04
STA $21
LDA #$00
STA $23
LDA #$18
STA $24
W2       LDX #$00
LDY #$00
W1       TXA
AND #$07
ASL A
ASL A
ASL A
CLC
ADC $23
STA ($20),Y
INX
INY
CPY #$28
BNE W1
INC $23
LDA $23
AND #$07
STA $23
W23      LDA $20
CLC
ADC #$28
STA $20
LDA $21
ADC #$00
STA $21
DEC $24
BPL W2
LDX #$00
LDA #$00
YU11     STA $3A10,X
CLC
ADC #$01
STA $3A10+$40,X
CLC
ADC #$01
STA $3A10+$80,X
CLC
ADC #$01
STA $3A10+$C0,X
CLC
ADC #$01
STA $3A10+$0100,X
CLC
ADC #$01
STA $3A10+$0140,X
CLC
ADC #$01
STA $3A10+$0180,X
CLC
ADC #$01
STA $3A10+$01C0,X
CLC
ADC #$01
INX
CPX #$18
BNE YU11
LDA #$FF
LDX #$27
DFG
STA $0680,X
STA $0680+$28,X
STA $0680+$50,X
STA $0680+$78,X
STA $0680+$A0,X
STA $0680+$C8,X
DEX
BPL DFG
RTS
CZYSC    LDX #$0F
LDA #$00
CZY1     STA $2000,X
STA $2020,X
STA $2040,X
STA $2060,X
STA $2080,X
STA $20A0,X
STA $20C0,X
STA $20E0,X
STA $2100,X
STA $2120,X
STA $2140,X
STA $2160,X
STA $2180,X
STA $21A0,X
STA $21C0,X
STA $21E0,X
STA $2010,X
STA $2030,X
STA $2050,X
STA $2070,X
STA $2090,X
STA $20B0,X
STA $20D0,X
STA $20F0,X
STA $2110,X
STA $2130,X
STA $2150,X
STA $2170,X
STA $2190,X
STA $21B0,X
STA $21D0,X
STA $21F0,X
DEX
BPL CZY1
RTS
MAKESIN  LDX #$3F
STX $20
LDA $21
CLC
ADC #$FE
STA $21
STA X1+1
LDA $22
CLC
ADC #$03
STA $22
STA X2+1
LDA $23
CLC
ADC #$01
STA $23
STA Y1+1
LDA $24
CLC
ADC #$02
STA $24
STA Y2+1
CLC
X1       LDA #$00
SPX1     ADC #$04
STA X1+1
TAX
X2       LDA #$00
SPX2     ADC #$08
STA X2+1
TAY
LDA SINTAB,X
ADC SINTAB,Y
LDX $20
STA TABX,X
Y1       LDA #$00
SPY1     ADC #$08
STA Y1+1
TAX
Y2       LDA #$00
SPY2     ADC #$04
STA Y2+1
TAY
LDA SINTAB,X
ADC SINTAB,Y
AND #$3F
LDX $20
STA TABY,X
DEC $20
BPL X1
RTS
PLOT     LDX #$00
PL1      LDY TABX,X
LDA TABHI,Y
STA $03
LDA TABLO,Y
STA $02
LDA TABAND,Y
LDY TABY,X
ORA ($02),Y
STA ($02),Y
DEX
BPL PL1
RTS
SPRINI
LDA #$C0
STA $D001
STA $D003
LDA #$0B
STA $D027
STA $D028
LDA #$20
STA $D000
LDA #$37
STA $D002
LDA #$0E80/64
STA $07F8
STA $07F9
LDA #$00
STA $D015
LDA #$00
STA $D01C
STA $D01D
STA $D01B
STA $D017
LDA #$02
STA $D010
RTS
MAKETAB  LDX #$00
M1       TXA
AND #$18
ASL A
ASL A
ASL A
STA TABLO,X
INX
BNE M1
LDX #$00
M2       TXA
AND #$20
LSR A
LSR A
LSR A
LSR A
LSR A
CLC
ADC #$20
STA TABHI,X
INX
BNE M2
CLC
LDX #$00
LDA #$80
M3       STA TABAND,X
ROR A
BNE M4
ROR A
M4       INX
BNE M3
RTS
PROC     LDY $2F
SSS      LDX $3900,Y
BUF      LDA $0800
STA $30
LDA #$00
C1       STA $3000,X
C2       STA $3000,X
C3       STA $3000,X
C4       STA $3000,X
C5       STA $3000,X
C6       STA $3000,X
LDY #$00
LDA ($30),Y
S11      STA $3000,X
INY
LDA ($30),Y
S22      STA $3000,X
INY
LDA ($30),Y
S33      STA $3000,X
INY
LDA ($30),Y
S44      STA $3000,X
INY
LDA ($30),Y
S55      STA $3000,X
INY
LDA ($30),Y
S66      STA $3000,X
INY
LDA ($30),Y
S77      STA $3000,X
.BYTE $01,$02,$03
PISZ     LDA #$00
STA $20
LDA #$50
STA $21
LDA #<PROC
STA $22
LDA #>PROC
STA $23
LDA #$01
STA $24
LDA #$40
STA $25
LDA #$30
STA $26
PI2
LDA $24
STA BUF+1
STA SSS+1
LDY $25
STY C1+1
INY
STY C2+1
INY
STY C3+1
INY
STY S11+1
INY
STY S22+1
INY
STY S33+1
INY
STY S44+1
INY
STY S55+1
INY
STY S66+1
INY
STY S77+1
INY
STY C4+1
INY
STY C5+1
INY
STY C6+1
LDY $26
STY C1+2
STY C2+2
STY C3+2
STY S11+2
STY S22+2
STY S33+2
STY S44+2
STY S55+2
STY S66+2
STY S77+2
STY C4+2
STY C5+2
STY C6+2
LDY #$48
PI1      LDA ($22),Y
STA ($20),Y
DEY
BPL PI1
LDA $20
CLC
ADC #$49
STA $20
LDA $21
ADC #$00
STA $21
LDA $25
CLC
ADC #$40
STA $25
LDA $26
ADC #$00
STA $26
INC $24
LDA $24
CMP #$17
BEQ PI22
JMP PI2
PI22     LDY #$00
LDA #$60
STA ($20),Y
RTS
SCRINI   LDA #>TEKST
STA TEXTHI
LDA #<TEKST
STA TEXTLO
RTS
SCROLL   LDA FAZA
SEC
SBC #$01
STA FAZA
BMI SCR1
RTS
SCR1     CLC
ADC #$08
STA FAZA
LDA $0801
STA $0800
LDA $0802
STA $0801
LDA $0803
STA $0802
LDA $0804
STA $0803
LDA $0805
STA $0804
LDA $0806
STA $0805
LDA $0807
STA $0806
LDA $0808
STA $0807
LDA $0809
STA $0808
LDA $080A
STA $0809
LDA $080B
STA $080A
LDA $080C
STA $080B
LDA $080D
STA $080C
LDA $080E
STA $080D
LDA $080F
STA $080E
LDA $0810
STA $080F
LDA $0811
STA $0810
LDA $0812
STA $0811
LDA $0813
STA $0812
LDA $0814
STA $0813
LDA $0815
STA $0814
LDA $0816
STA $0815
LDA $0817
STA $0816
LDY #$00
LDA (TEXTLO),Y
BEQ SCR2
AND #$1F
ASL A
ASL A
ASL A
JMP SCR22
SCR2     JSR SCRINI
LDA #$00
SCR22    BIT $00
STA $0817
LDA TEXTLO
CLC
ADC #$01
STA TEXTLO
LDA TEXTHI
ADC #$00
STA TEXTHI
RTS
BUJANIE
LDX $0D
INX
LDA #$FF
STA $0680,X
STA $0680+$28,X
STA $0680+$50,X
STA $0680+$78,X
STA $0680+$A0,X
STA $0680+$C8,X
INX
STA $0680,X
STA $0680+$28,X
STA $0680+$50,X
STA $0680+$78,X
STA $0680+$A0,X
STA $0680+$C8,X
LDX $0F
LDA $3C00,X
CLC
ADC FAZA
TAY
AND #$07
ORA #$C0
STA $0E
TYA
LSR A
LSR A
LSR A
STA $0D
CLC
ADC #$19
TAX
LDY #$19
BU1
LDA $3A4F,Y
STA $0680,X
LDA $3A8F,Y
STA $0680+$28,X
LDA $3ACF,Y
STA $0680+$50,X
LDA $3B0F,Y
STA $0680+$78,X
LDA $3B4F,Y
STA $0680+$A0,X
LDA $3B8F,Y
STA $0680+$C8,X
DEX
DEY
BNE BU1
INC $0F
H1       RTS
LOGO
LDX #$27
KP1      LDA #$FF
WAIT1    CMP $D012
BNE WAIT1
WAIT2    CMP $D012
BEQ WAIT2
LDA $0C00,X
STA $04A0,X
LDA $0B00,X
STA $D8A0,X
LDA $0C28,X
STA $04C8,X
LDA $0B28,X
STA $D8C8,X
LDA $0C50,X
STA $04F0,X
LDA $0B50,X
STA $D8F0,X
LDA $0C78,X
STA $0518,X
LDA $0B78,X
STA $D918,X
LDA $0CA0,X
STA $0540,X
LDA $0BA0,X
STA $D940,X
LDA $0CC8,X
STA $0568,X
LDA $0BC8,X
STA $D968,X
DEX
BPL KP1
RTS
LOGOUT
LDX #$04
STX $02
KP13     LDY #$02
KP11     LDA #$FF
WAIT11   CMP $D012
BNE WAIT11
WAIT21   CMP $D012
BEQ WAIT21
DEY
BPL KP11
LDX #$00
KP22     LDY $04A0,X
LDA $3E00,Y
STA $04A0,X
LDY $D8A0,X
LDA $3E00,Y
STA $D8A0,X
INX
CPX #$F0
BNE KP22
DEC $02
BPL KP13
RTS
TEKST    .TEXT "     I HOPE YOU LIKE"
.TEXT " THIS INTRO\ AS MUCH "
.TEXT "AS I\ COZ THIS IS ONE "
.TEXT "OF MY BEST INTROS SO "
.TEXT "FAR[        ALL CODE "
.TEXT "BY SIR ART\ LOGO BY "
.TEXT "STONE\ FONTS BY HEDGE"
.TEXT "HOG AND MUSIC COMPOSED"
.TEXT " BY COMPOD IN JCH^S PL"
.TEXT "AYER\ WHICH GIVES IT "
.TEXT "SPECIAL KIND OF FEELIN"
.TEXT "G[                    "
.TEXT "                      "
.TEXT "            END]      "
.TEXT "                      "
.TEXT "                      "
.BYTE $00